echo off
rem
rem *** Listing 3-4 ***
rem
rem *****************************************************************
rem * Ce fichier PZTIME.BAT construit et exécute le timer Zen       *
rem * de précision PZTEST.EXE pour mesurer le code du parametre     *
rem * de la ligne de commande                                       *
rem * Le Listing 3-1 doit être appelé PZTIMER.ASM et le Listing 3-2 *
rem * PZTEST.ASM. Pour mesurer le code du LST3-3,vous devez entrer  *
rem * la commande DOS suivante:                                     *
rem *                                                               *
rem * pztime lst3-3                                                 *
rem *                                                               *
rem * MASM et LINK doivent être dans le répertoire courant ou dans  *
rem * le chemin courant pour que ce fichier batch fonctionne.       *
rem *                                                               *
rem * Pour utiliser ce fichier avec Turbo Assembler, changez        *
rem * les commandes masm en tasm puis la commande link en tlink.    *
rem *                                                               *
rem * Ce fichier batch peut être accéléré en assemblant PZTIMER.ASM *
rem * en une première fois, puis en supprimant ces lignes:          *
rem *                                                               *
rem * masm pztimer;                                                 *
rem * if errorlevel 1 goto errorend                                 *
rem *                                                               *
rem * de ce fichier.                                                *
rem *                                                               *
rem * Par Michael Abrash                                            *
rem *****************************************************************
rem
rem s'assure que le fichier test a été spécifié.
rem
if not x%1==x goto ckexist
echo ****************************************************************
echo * Specifiez le fichier test.                                   *
echo ****************************************************************
goto end
rem
rem Vérifie si le fichier existe.
rem
:ckexist
if exist %1 goto docopy
echo ****************************************************************
echo * Le fichier spécifié, "%1," n'existe pas.                     * 
echo ****************************************************************
goto end
rem
rem copie le fichier à mesurer dans TESTCODE.
rem
:docopy
copy %1 testcode
masm pztest;
if errorlevel 1 goto errorend
masm pztimer;
if errorlevel 1 goto errorend
link pztest+pztimer;
if errorlevel 1 goto errorend
pztest
goto end
:errorend
echo ****************************************************************
echo * Une erreur est apparue lors de la construction du            * 
.    * du Timer Zen de précision                                    * 
echo ****************************************************************
:end