echo off
rem
rem *** Listing 3-7 ***
rem
rem *****************************************************************
rem * Fichier LZTIME.BAT qui construit et exécute le programme     *
rem * du timer Zen à période longue LZTEST.EXE pour mesurer le code *
rem * nommé comme paramètre de la ligne de commande. Le Listing 3-5 *
rem * est dans LZTIMER.ASM, et le Listing 3-6 est dans              *
rem * LZTEST.ASM. pour mesurer le code dans LST3-8, vous devrez     *
rem * entrer la commande DOS :                                      *
rem *                                                               *
rem * lztime lst3-8                                                 *
rem *                                                               *
rem * MASM and LINK doivent être dans le répertoire courant ou      *
rem * dans le chemin courant pour que ce fichier batch fonctionne.  *
rem *                                                               *
rem * Ce fichier batch peut être accéléré en assemblant LZTIMER.ASM *
rem * en une première fois, puis en supprimant ces lignes:          *                 *
rem *                                                               *
rem * masm lztimer;                                                 *
rem * if errorlevel 1 goto errorend                                 *
rem *                                                               *
rem * de ce fichier.                                                *
rem *                                                               *
rem * Par Michael Abrash                                            *
rem *****************************************************************
rem
rem Vérifiez si le fichier test a été spécifié.
rem
if not x%1==x goto ckexist
echo ***************************************************************
echo * Spécifiez le fichier test.                                  *
echo ***************************************************************
goto end
rem
rem Vérifiez si le fichier existe.
rem
:ckexist
if exist %1 goto docopy
echo ***************************************************************
echo * Le fichier spécifié, "%1," n'existe pas.                    *
echo ***************************************************************
goto end
rem
rem copiez le fichier à mesurer dans TESTCODE.
:docopy
copy %1 testcode
masm lztest;
if errorlevel 1 goto errorend
masm lztimer;
if errorlevel 1 goto errorend
link lztest+lztimer;
if errorlevel 1 goto errorend
lztest
goto end
:errorend
echo ***************************************************************
echo * Une erreur est apparue lors de la construction du Timer     * 
echo * Zen à période longue.                                       *
echo ***************************************************************
:end