; Tri d'un tableau de INT. Appelable depuis C (en modèle small).25 octets. 
; void sort( int num, int a[] ); 
; 
; Avec l'aimable autorisation de David Stafford. 
;----------------------------------------------------------- 
                                  
                    .model        small 
                    .code         
                    public        _sort 
                                  
top:                mov           dx,[bx]   ;permute deux entiers adjacents  
                    xchg          dx,[bx+2] 
                    xchg          dx,[bx] 
                    cmp           dx,[bx]   ;sont-ils dans le bon ordre? 
                    jl            top       ;non, les permuter 
                    inc           bx        ;passez au prochain entier 
                    inc           bx 
                    loop          top 
_sort:              pop           dx        ;récupère l'adresse de retour (point
                                            ;d'entrée) 
                    pop           cx        ;récupère le compte 
                    pop           bx        ;récupère le pointeur 
                    push          bx        ;restaure le pointeur 
                    dec           cx        ;décremente le compte 
                    push          cx        ;sauve le compte 
                    push          dx        ;restaure l'adresse de retour 
                    jg            top ;si cx > 0 
                    ret           
                    end