; Trouve la valeur unsigned int la plus grande ou la plus petite. 
; appelable depuis C (modèle small). 
; 24 octets. 
; Par David Stafford. 
; unsigned hi( int num, unsigned a[] ); 
; unsigned lo( int num, unsigned a[] ); 
;-------------------------------------------- 
                                  
                    public        _hi, _lo 
                                  
_hi:                db            0b9h      ;mov cx, immédiate 
_lo:                xor           cx,cx 
                                  
                    pop           ax        ;récupère l'adresse de retour  
                    pop           dx        ;récupère le compteur  
                    pop           bx        ;récupère le pointeur  
                    push          bx        ;restaure le pointeur 
                    push          dx        ;restaure le compteur  
                    push          ax        ;restaure l'adresse de retour 
                                  
save:               mov           ax,[bx] 
top:                cmp           ax,[bx] 
                    jcxz          around 
                    cmc           
around:             ja            save 
                    inc           bx 
                    inc           bx 
                    dec           dx 
                    jnz           top 
                                  
                    ret